Control your DVD/CD drive with Dragon: AutoHotkey/Vocola

This script to control your CD/DVD drive by voice is optionally twofold. It requires AutoHotkey to assign it to a keypress, and Vocola or another Dragon NaturallySpeaking add-on to assign a voice command to that key if you wish. You would thus need to be running both for the latter to work. (See Product Sites sidebar to download.) If you don’t have an add-on program, you can do this by running only the AutoHotkey script and vocally pressing the key. Choose a key that you don’t use very often; mine is the | (vertical bar). If you absolutely need that key for something, exclude the application that requires it. (E.g. IfWinExist [, WinTitle, WinText, ExcludeTitle, ExcludeText]).

Telling Dragon to press that key or its command will both eject and close the tray, depending on its current position. I did try to do this using only Vocola, but AutoHotkey made it easier because it has that as a built-in script in its list of commands.

The AutoHotkey script:

|::
Drive, Eject
if A_TimeSinceThisHotkey < 1000
Drive, Eject,, 1
return

The Vocola script:

Drive (open | close) = {|};

Vocola commands for Win32Pad

# Voice commands for win32pad

new document = {Ctrl+n};
open document = {Ctrl+o};
save document = {Ctrl+s};
Go to line 1..50 = {Ctrl+g} $1 {Enter};
delete line 1..50 ={Ctrl+g} $1 {Enter} {Ctrl+y};
indent = {Tab};
unindent = {Shift+Tab};

Vocola commands for Tetris

These commands apply to the version of Tetris I mentioned in my previous post.

# Voice commands for tetris

New game = {F2};

flip (left = {NumKey8} | right = {NumKey5}) 1..4 = $1_$2;

drop = {NumKey2};

(pause | resume) = {F3};

Click Firefox links with the apostrophe ‘ and Dragon

The auto scrolling bookmarklet prompted me to write this post, but the fix I’m going to describe applies to Firefox globally as well. I said earlier that the bookmarklet’s number key speed shortcuts conflicted with Mouseless Browsing, but even if you’re not using Mouseless Browsing, it also conflicts with the accessibility.typeaheadfind settings in Firefox’s about:config. So, if you say or type a number to finely adjust the speed (you can also, it turns out, just press the + or – as long as you’re not using Mouse Keys), your speed will adjust, but Firefox will focus on where that number appears. Therefore, chances are good you’ll lose your place in whatever you’re reading.

However, there is a way to access links reliably without either typeaheadfind or Mouseless Browsing turned on. Just press or say apostrophe. This will temporarily turn on the accessibility.typeaheadfind.linksonly setting, and you can say or type your link word, then press Enter. However, you may still wish to go into about:config and turn off the timeout setting if you’re a keyboard user and type slowly.

Compared to having the setting enabled automatically, this is a slightly clumsier process, especially if you have a keyboard on which the ‘ is a shifted key. It would be somewhat more bearable for Dragon users, though, especially if you could create an add-on command. Here is my Vocola command, taken from my list of Firefox commands:

[Click] Link <_anything> = “‘” $1 {Enter};

That was a basic clicking link, but if you want to account for opening a link in a new tab, here is the command:

[Open] Link <_anything> new tab = “‘” $1 {Ctrl+Enter};

Now you should be able to keep your place while you scroll. Also, you might want to use this command anyway, because even though Dragon will occasionally click a Firefox link for you, Dragon itself does not have a way to open a new tab when it clicks something.

Restart Dragon vocally: Vocola

To use certain memory intensive programs, I not only have to end unnecessary processes, but also temporarily turn off the functions in Dragon I don’t need for that particular program. (I’ll go into this more when I talk about using Visual C++ for my programming homework.) For example, I disable the HTML commands if the memory sucker doesn’t require the internet. When I’m done, I enable them again. The unfortunate side effect is that Dragon requires a restart for the change to take effect. For some stupid reason, there’s no native restart command (in Preferred, anyway). This can be a problem if you’re totally voice dependent. Thus a Vocola command:

Dragon restart = HeardWord(close, naturally, speaking) Wait(7000) AppBringUp (“C:\Program Files\Nuance\NaturallySpeaking10\Program\natspeak.exe”);

Note that even if you have set the microphone to start asleep (yellow), it may remain green as the restart command executes.

Mouseless Browsing and Dragon: how to open links in new tabs

Opening links in a new tab with Dragon is a useful function, and can be done through Mouseless Browsing. You can do this with or without Vocola, but the Vocola command is a lot quicker.

With Vocola: Go into the mouseless browsing configuration and make sure the postfix key for opening links in a new tab is the plus sign (found under the Keys menu) and the modifier key is Ctrl (found under ID types). Then edit your Firefox voice commands by adding the following script, where 1..1000 corresponds to the link number you want to say:

Open 1..1000 new tab = $1{+}{Ctrl+Enter};

Without Vocola: Go into the mouseless browsing configuration and make sure the postfix key is the plus sign, and the modifier is Ctrl, as above. Then, say “press [number] plus-sign.” Then, say “press Control Enter.”

Bypassing text fields in mouseless browsing

My list of Vocola commands for Firefox is getting pretty long, so I figure I should start breaking it up. Since a lot of Firefox use with Dragon involves mouseless browsing, I thought it would be a good idea to post specific Vocola commands that allow you to take advantage of more mouseless browsing capabilities than you’d be able to if you were just using Dragon alone.

You may have noticed that if your cursor is in a text box, and you want to say a link, saying “numeral [whatever]” puts those numbers in the text box instead of clicking the link you want. Not terribly helpful. The 1st thing you want to do is go into Tools — Add-ons — Mouseless Browsing (or, if you have your mouseless browsing options in your Tools menu separately, just Tools — Mouseless Browsing — Open Configuration). Then, choose “ID types.” Check the option “use numpad exclusively for mouseless browsing.” As per the description, this allows you to bypass text fields and go directly to the link. For Dragon, however, you need Vocola or another scripting program in order to make use of this feature.

The reason is that Dragon cannot natively press more than one keypad key in succession. You need to make a command that will force Dragon to press only the keypad keys, and in such a way that you can enter multiple digit link numbers. Like so:

0..9..0..9..0..9..09 = {NumKey$1}{NumKey$2}{NumKey$3}{NumKey$4};
0..9 0..9 0..9 = {NumKey$1}{NumKey$2}{NumKey$3};
0..9 0..9 = {NumKey$1}{NumKey$2};
0..9 = {NumKey$1};

So, for example, if I say “2  7  3″ while my blinking cursor is in the text box, Dragon will press those three keys on the keypad as if you had pressed them manually. The focus will now transfer to the link and press it. Perfect. (NOTE: under the mouseless browsing options, make sure the option “execute automatically without pressing enter” is checked.)

Vocola commands for Foxit Reader

These commands work equally in version 2.3 and 3 except for the typewriter command — in version 2.3, the sent key press is {Alt+8}. This is not an exhaustive list of commands; it’s just the ones I use frequently. If there are any discrepancies between the 2 versions that I’ve missed, let me know.

# Voice commands for foxit reader

open doc = {Ctrl+o};
save doc = {Ctrl+s};
print doc = {Ctrl+p};
close tab = {Ctrl+w};
next tab = {Ctrl+Tab};
search for <_anything> = {Ctrl+Shift+f} $1 {Enter};
close search pane = SetMousePosition(1, 1011, 91) ButtonClick();
auto scroll (on | off) = {Ctrl+Shift+h};
typewriter = {Alt+t}{t}{Enter};
font menu = SetMousePosition(1, 112, 94) ButtonClick();
change font size = SetMousePosition(1, 241, 94) ButtonClick();
notes = {Alt+t}{c}{n};
text view (on | off) = {Alt+9};
choose text = {Alt+6};
highlight text = {Alt+t}{c}{h};
Zoom in = {Alt+5};
Zoom out = {Alt+4};
hand = {Alt+3};
jump to page 1..100 = {Ctrl+Shift+n} $1 {Enter};
Zoom to = {Ctrl+m};

Vocola commands for Firefox

This list is very much a work in progress — Firefox works surprisingly well vocally if you have mouseless browsing installed, and your toolbars are customized the right way. The “click link” command allows you to go without mouseless browsing if you want to, though — for the most part. You can speak any part of the link as long as it’s a pronounceable word. I haven’t figured out the whole text field or button/checkbox thing, except to get the mouse coordinates or count tab keys.

UPDATE: I’ve pared this down to the essentials, to be updated as I find things.

# Voice commands for firefox

Middle click = ButtonClick(4,1);
Enable select say = SetNaturalText(1);
[Click] Link <_anything> = “‘” $1 {Enter};
Organize bookmarks = {Ctrl+Shift+b};
Clear private data = {Ctrl+Shift+Del};
options menu = {Alt+t} Wait(400) {Up} {Enter};

#mouseless browsing

0..9 0..9 0..9 = {NumKey$1}{NumKey$2}{NumKey$3};

0..9 0..9 = {NumKey$1}{NumKey$2};

0..9 = {NumKey$1};

Open 1..1000 new tab = $1{+}{Ctrl+Enter};

(Disable | enable) mouseless browsing = {Alt+NumKey.};

#autoscrolling (bookmarklet)

Stop scrolling = {Esc};

Scroll faster = {Ctrl+Shift+NumKey+};

Scroll slower = {Ctrl+Shift+NumKey-};

Vocola commands for Media Player 10

Here are my commands for Windows Media Player (version 10). If you want to use the captioning command, you have to wait until a couple seconds after the movie actually begins to play. If you want to, you could make the “eject” command global so that it would open the drive whenever you wanted.

# Voice commands for wmplayer

Eject = {Ctrl+e};
Stop = {Ctrl+s};
Fast-forward = {Ctrl+Shift+f};
Rewind = {Ctrl+Shift+b};
Pause = {Ctrl+p};
Play = {Ctrl+p};
Captions = {Alt+p}{b}{e};
Burn = {Alt+b};
Full-screen = {Alt+Enter};